mirror of
https://git.sr.ht/~rabbits/uxn
synced 2024-11-23 14:25:10 +00:00
121 lines
2.9 KiB
Tal
121 lines
2.9 KiB
Tal
( dev/mouse )
|
|
|
|
%RTN { JMP2r }
|
|
%ABS2 { DUP2 #0f SFT2 EQU #04 JCN #ffff MUL2 }
|
|
%LTS2 { #8000 ADD2 SWP2 #8000 ADD2 GTH2 }
|
|
%GTS2 { #8000 ADD2 SWP2 #8000 ADD2 LTH2 }
|
|
%2** { #10 SFT2 }
|
|
|
|
( devices )
|
|
|
|
|00 @System [ &vector $2 &pad $6 &r $2 &g $2 &b $2 ]
|
|
|20 @Screen [ &vector $2 &width $2 &height $2 &pad $2 &x $2 &y $2 &addr $2 &pixel $1 &sprite $1 ]
|
|
|90 @Mouse [ &vector $2 &x $2 &y $2 &state $1 &wheel $1 ]
|
|
|
|
|0000
|
|
|
|
@color $1
|
|
@line [ &x0 $2 &y0 $2 &x $2 &y $2 &sx $2 &sy $2 &dx $2 &dy $2 &e1 $2 &e2 $2 ]
|
|
@pointer [ &x $2 &y $2 &lastx $2 &lasty $2 &state $1 ]
|
|
|
|
( program )
|
|
|
|
|0100 ( -> )
|
|
|
|
( theme )
|
|
#f030 .System/r DEO2
|
|
#f04f .System/g DEO2
|
|
#f050 .System/b DEO2
|
|
|
|
( vectors )
|
|
;on-mouse .Mouse/vector DEO2
|
|
|
|
BRK
|
|
|
|
@on-mouse ( -> )
|
|
|
|
;draw-cursor JSR2
|
|
|
|
( on down )
|
|
.Mouse/state DEI #00 NEQ .pointer/state LDZ #00 EQU #0101 EQU2 ,on-mouse-down JCN
|
|
|
|
( on drag )
|
|
.Mouse/state DEI ,on-mouse-drag JCN
|
|
.Mouse/state DEI .pointer/state STZ
|
|
|
|
BRK
|
|
|
|
@on-mouse-down ( -> )
|
|
|
|
( record start position )
|
|
.Mouse/x DEI2 DUP2 .pointer/x STZ2 .pointer/lastx STZ2
|
|
.Mouse/y DEI2 DUP2 .pointer/y STZ2 .pointer/lasty STZ2
|
|
.Mouse/state DEI .pointer/state STZ
|
|
|
|
BRK
|
|
|
|
@on-mouse-drag ( -> )
|
|
|
|
( draw line )
|
|
.pointer/lastx LDZ2
|
|
.pointer/lasty LDZ2
|
|
.pointer/x LDZ2
|
|
.pointer/y LDZ2
|
|
#01 [ .Mouse/state DEI #10 EQU #02 MUL ADD ]
|
|
;draw-line JSR2
|
|
|
|
( record last position )
|
|
.Mouse/x DEI2 .pointer/lastx STZ2
|
|
.Mouse/y DEI2 .pointer/lasty STZ2
|
|
.Mouse/state DEI .pointer/state STZ
|
|
|
|
BRK
|
|
|
|
@draw-cursor ( -- )
|
|
|
|
;pointer_icn .Screen/addr DEO2
|
|
( clear last cursor )
|
|
.pointer/x LDZ2 .Screen/x DEO2
|
|
.pointer/y LDZ2 .Screen/y DEO2
|
|
#40 .Screen/sprite DEO
|
|
|
|
( record pointer positions )
|
|
.Mouse/x DEI2 .pointer/x STZ2
|
|
.Mouse/y DEI2 .pointer/y STZ2
|
|
|
|
( draw new cursor )
|
|
.pointer/x LDZ2 .Screen/x DEO2
|
|
.pointer/y LDZ2 .Screen/y DEO2
|
|
#43 .Mouse/state DEI #00 NEQ #02 MUL SUB .Screen/sprite DEO
|
|
|
|
RTN
|
|
|
|
@draw-line ( x1 y1 x2 y2 color -- )
|
|
|
|
( load ) .color STZ .line/y0 STZ2 .line/x0 STZ2 .line/y STZ2 .line/x STZ2
|
|
.line/x0 LDZ2 .line/x LDZ2 SUB2 ABS2 .line/dx STZ2
|
|
.line/y0 LDZ2 .line/y LDZ2 SUB2 ABS2 #0000 SWP2 SUB2 .line/dy STZ2
|
|
#ffff #00 .line/x LDZ2 .line/x0 LDZ2 LTS2 2** ADD2 .line/sx STZ2
|
|
#ffff #00 .line/y LDZ2 .line/y0 LDZ2 LTS2 2** ADD2 .line/sy STZ2
|
|
.line/dx LDZ2 .line/dy LDZ2 ADD2 .line/e1 STZ2
|
|
&loop
|
|
.line/x LDZ2 .Screen/x DEO2
|
|
.line/y LDZ2 .Screen/y DEO2
|
|
.color LDZ .Screen/pixel DEO
|
|
[ .line/x LDZ2 .line/x0 LDZ2 EQU2 ]
|
|
[ .line/y LDZ2 .line/y0 LDZ2 EQU2 ] #0101 EQU2 ,&end JCN
|
|
.line/e1 LDZ2 2** .line/e2 STZ2
|
|
.line/e2 LDZ2 .line/dy LDZ2 LTS2 ,&skipy JCN
|
|
.line/e1 LDZ2 .line/dy LDZ2 ADD2 .line/e1 STZ2
|
|
.line/x LDZ2 .line/sx LDZ2 ADD2 .line/x STZ2
|
|
&skipy
|
|
.line/e2 LDZ2 .line/dx LDZ2 GTS2 ,&skipx JCN
|
|
.line/e1 LDZ2 .line/dx LDZ2 ADD2 .line/e1 STZ2
|
|
.line/y LDZ2 .line/sy LDZ2 ADD2 .line/y STZ2
|
|
&skipx
|
|
;&loop JMP2
|
|
&end
|
|
|
|
RTN
|
|
|
|
@pointer_icn [ 80c0 e0f0 f8e0 1000 ]
|