mirror of
https://git.sr.ht/~rabbits/uxn
synced 2024-11-05 13:55:06 +00:00
606 lines
16 KiB
Tal
606 lines
16 KiB
Tal
( piano )
|
|
|
|
%+ { ADD } %- { SUB } %* { MUL } %/ { DIV }
|
|
%< { LTH } %> { GTH } %= { EQU } %! { NEQ }
|
|
%++ { ADD2 } %-- { SUB2 } %** { MUL2 } %// { DIV2 }
|
|
%<< { LTH2 } %>> { GTH2 } %== { EQU2 } %!! { NEQ2 }
|
|
|
|
%RTN { JMP2r }
|
|
%TOS { #00 SWP }
|
|
%MOD { DUP2 / * - }
|
|
%LTS2 { #8000 ++ SWP2 #8000 ++ >> }
|
|
%GTS2 { #8000 ++ SWP2 #8000 ++ << }
|
|
%INCR { SWP #01 + SWP }
|
|
%2// { #01 SFT2 }
|
|
%4// { #02 SFT2 }
|
|
%8// { #03 SFT2 }
|
|
%8** { #30 SFT2 }
|
|
|
|
( devices )
|
|
|
|
|00 @System [ &vector $2 &pad $6 &r $2 &g $2 &b $2 ]
|
|
|10 @Console [ &vector $2 &read $1 &pad $5 &write $1 ]
|
|
|20 @Screen [ &vector $2 &width $2 &height $2 &pad $2 &x $2 &y $2 &addr $2 &color $1 ]
|
|
|30 @Audio0 [ &vector $2 &position $2 &output $1 &pad $3 &adsr $2 &length $2 &addr $2 &volume $1 &pitch $1 ]
|
|
|70 @Midi [ &vector $2 &channel $1 ¬e $1 &velocity $1 ]
|
|
|80 @Controller [ &vector $2 &button $1 &key $1 ]
|
|
|90 @Mouse [ &vector $2 &x $2 &y $2 &state $1 &wheel $1 ]
|
|
|a0 @File [ &vector $2 &success $2 &offset $2 &pad $2 &name $2 &length $2 &load $2 &save $2 ]
|
|
|
|
( variables )
|
|
|
|
|0000
|
|
|
|
@last-note $1
|
|
@octave $1
|
|
@color $1
|
|
@pointer [ &x $2 &y $2 ]
|
|
@center [ &x $2 &y $2 ]
|
|
@adsr-view [ &x1 $2 &y1 $2 &x2 $2 &y2 $2 ]
|
|
@wave-view [ &x1 $2 &y1 $2 &x2 $2 &y2 $2 ]
|
|
@octave-view [ &x1 $2 &y1 $2 &x2 $2 &y2 $2 ]
|
|
|
|
( program )
|
|
|
|
|0100 ( -> )
|
|
|
|
( theme )
|
|
#0fe5 .System/r DEO2
|
|
#0fc5 .System/g DEO2
|
|
#0f25 .System/b DEO2
|
|
|
|
( vectors )
|
|
;on-frame .Screen/vector DEO2
|
|
;on-control .Controller/vector DEO2
|
|
;on-mouse .Mouse/vector DEO2
|
|
;on-message .Console/vector DEO2
|
|
|
|
( find center )
|
|
.Screen/width DEI2 2// .center/x STZ2
|
|
.Screen/height DEI2 2// .center/y STZ2
|
|
|
|
( place octave )
|
|
.center/x LDZ2 #0080 -- .octave-view/x1 STZ2
|
|
.center/y LDZ2 #0008 ++ .octave-view/y1 STZ2
|
|
.octave-view/x1 LDZ2 #0050 ++ .octave-view/x2 STZ2
|
|
.octave-view/y1 LDZ2 #0018 ++ .octave-view/y2 STZ2
|
|
|
|
( place adsr )
|
|
.center/x LDZ2 #0020 -- .adsr-view/x1 STZ2
|
|
.center/y LDZ2 #0008 ++ .adsr-view/y1 STZ2
|
|
.adsr-view/x1 LDZ2 #00a0 ++ .adsr-view/x2 STZ2
|
|
.adsr-view/y1 LDZ2 #0018 ++ .adsr-view/y2 STZ2
|
|
|
|
( place waveform )
|
|
.center/x LDZ2 #0080 -- .wave-view/x1 STZ2
|
|
.center/y LDZ2 #0020 -- .wave-view/y1 STZ2
|
|
.wave-view/x1 LDZ2 #0100 ++ .wave-view/x2 STZ2
|
|
.wave-view/y1 LDZ2 #0020 ++ .wave-view/y2 STZ2
|
|
|
|
( default settings )
|
|
#ff .last-note STZ
|
|
#041c .Audio0/adsr DEO2
|
|
#88 .Audio0/volume DEO
|
|
;piano-pcm .Audio0/addr DEO2
|
|
#0100 .Audio0/length DEO2
|
|
|
|
( inital drawing )
|
|
;draw-octave JSR2
|
|
;draw-adsr JSR2
|
|
;draw-wave JSR2
|
|
|
|
BRK
|
|
|
|
@on-frame ( -> )
|
|
|
|
.adsr-view/y2 LDZ2 #0020 -- .Screen/y DEO2
|
|
|
|
#00 #10
|
|
&loop
|
|
.adsr-view/x2 LDZ2 #003a -- .Screen/x DEO2
|
|
OVR #10 SWP - .Audio0/output DEI #0f AND < .Screen/color DEO
|
|
.adsr-view/x2 LDZ2 #003a -- #0002 ++ .Screen/x DEO2
|
|
OVR #10 SWP - .Audio0/output DEI #04 SFT < .Screen/color DEO
|
|
.Screen/y DEI2 #0002 ++ .Screen/y DEO2
|
|
( incr ) INCR
|
|
LTHk ,&loop JCN
|
|
POP2
|
|
|
|
BRK
|
|
|
|
@on-control ( -> )
|
|
|
|
( clear last cursor )
|
|
.pointer/x LDZ2 .Screen/x DEO2
|
|
.pointer/y LDZ2 .Screen/y DEO2
|
|
#30 .Screen/color DEO
|
|
|
|
.Controller/key DEI
|
|
DUP #61 ! ,&no-c JCN
|
|
#30 .octave LDZ #0c * + ;play JSR2 &no-c
|
|
DUP #73 ! ,&no-d JCN
|
|
#32 .octave LDZ #0c * + ;play JSR2 &no-d
|
|
DUP #64 ! ,&no-e JCN
|
|
#34 .octave LDZ #0c * + ;play JSR2 &no-e
|
|
DUP #66 ! ,&no-f JCN
|
|
#35 .octave LDZ #0c * + ;play JSR2 &no-f
|
|
DUP #67 ! ,&no-g JCN
|
|
#37 .octave LDZ #0c * + ;play JSR2 &no-g
|
|
DUP #68 ! ,&no-a JCN
|
|
#39 .octave LDZ #0c * + ;play JSR2 &no-a
|
|
DUP #6a ! ,&no-b JCN
|
|
#3b .octave LDZ #0c * + ;play JSR2 &no-b
|
|
DUP #6b ! ,&no-c2 JCN
|
|
#3c .octave LDZ #0c * + ;play JSR2 &no-c2
|
|
POP
|
|
|
|
( release )
|
|
#00 .Controller/key DEO
|
|
|
|
.Controller/button DEI #f0 AND
|
|
DUP #04 SFT #01 AND #01 ! ,&no-up JCN
|
|
( move ) .Audio0/addr DEI2 #0001 -- .Audio0/addr DEO2 &no-up
|
|
DUP #05 SFT #01 AND #01 ! ,&no-down JCN
|
|
( move ) .Audio0/addr DEI2 #0001 ++ .Audio0/addr DEO2 &no-down
|
|
DUP #06 SFT #01 AND #01 ! ,&no-left JCN
|
|
( move ) .Audio0/addr DEI2 #0010 -- .Audio0/addr DEO2 &no-left
|
|
DUP #07 SFT #01 AND #01 ! ,&no-right JCN
|
|
( move ) .Audio0/addr DEI2 #0010 ++ .Audio0/addr DEO2 &no-right
|
|
POP
|
|
|
|
;draw-octave JSR2
|
|
;draw-wave JSR2
|
|
|
|
BRK
|
|
|
|
@on-message ( -> )
|
|
|
|
.Console/read DEI ;play JSR2
|
|
;draw-octave JSR2
|
|
|
|
BRK
|
|
|
|
@on-mouse ( -> )
|
|
|
|
;draw-cursor JSR2
|
|
|
|
.Mouse/state DEI #00 ! #01 JCN [ BRK ]
|
|
|
|
.Mouse/x DEI2 .Mouse/y DEI2 .wave-view ;within-rect JSR2
|
|
;on-touch-wave-view JCN2
|
|
.Mouse/x DEI2 .Mouse/y DEI2 .adsr-view ;within-rect JSR2
|
|
;on-touch-adsr-view JCN2
|
|
.Mouse/x DEI2 .Mouse/y DEI2 .octave-view ;within-rect JSR2
|
|
;on-touch-octave-view JCN2
|
|
|
|
BRK
|
|
|
|
@on-touch-wave-view ( -> )
|
|
|
|
.Mouse/x DEI2 .wave-view/x1 LDZ2 -- .Audio0/length DEO2
|
|
;draw-wave JSR2
|
|
;draw-cursor JSR2
|
|
|
|
BRK
|
|
|
|
@on-touch-octave-view ( -> )
|
|
|
|
.Mouse/x DEI2 .octave-view/x1 LDZ2 -- 8// SWP POP #09 ! ,&no-mod JCN
|
|
.Mouse/y DEI2 .octave-view/y1 LDZ2 -- 8// SWP POP
|
|
DUP #00 ! ,&no-incr JCN
|
|
.octave LDZ #01 + .octave STZ &no-incr
|
|
DUP #02 ! ,&no-decr JCN
|
|
.octave LDZ #01 - .octave STZ &no-decr
|
|
POP
|
|
( release ) #00 .Mouse/state DEO
|
|
;draw-octave JSR2
|
|
BRK
|
|
&no-mod
|
|
|
|
.Mouse/x DEI2 .octave-view/x1 LDZ2 -- 8// SWP POP #06 > ,&no-key JCN
|
|
.Mouse/x DEI2 .octave-view/x1 LDZ2 -- 8// ;notes ++ LDA .octave LDZ #0c * + ;play JSR2
|
|
( release ) #00 .Mouse/state DEO
|
|
;draw-octave JSR2
|
|
&no-key
|
|
|
|
BRK
|
|
|
|
@on-touch-adsr-view ( -> )
|
|
|
|
.Mouse/x DEI2 .adsr-view/x1 LDZ2 -- 8// SWP POP #03 /
|
|
DUP #00 ! ,&no-a JCN
|
|
.Audio0/adsr DEI
|
|
#10 .Mouse/state DEI #10 = #e0 * + +
|
|
.Audio0/adsr DEO &no-a
|
|
DUP #01 ! ,&no-d JCN
|
|
.Audio0/adsr DEI
|
|
DUP #f0 AND STH #01 .Mouse/state DEI #10 = #0e * + + #0f AND STHr +
|
|
.Audio0/adsr DEO &no-d
|
|
DUP #02 ! ,&no-s JCN
|
|
.Audio0/adsr #01 + DEI
|
|
#10 .Mouse/state DEI #10 = #e0 * + +
|
|
.Audio0/adsr #01 + DEO &no-s
|
|
DUP #03 ! ,&no-r JCN
|
|
.Audio0/adsr #01 + DEI
|
|
DUP #f0 AND STH #01 .Mouse/state DEI #10 = #0e * + + #0f AND STHr +
|
|
.Audio0/adsr #01 + DEO &no-r
|
|
DUP #05 ! ,&no-left JCN
|
|
.Audio0/volume DEI
|
|
#10 .Mouse/state DEI #10 = #e0 * + +
|
|
.Audio0/volume DEO &no-left
|
|
DUP #06 ! ,&no-right JCN
|
|
.Audio0/volume DEI
|
|
DUP #f0 AND STH #01 .Mouse/state DEI #10 = #0e * + + #0f AND STHr +
|
|
.Audio0/volume DEO &no-right
|
|
POP
|
|
|
|
( release ) #00 .Mouse/state DEO
|
|
;draw-adsr JSR2
|
|
;draw-cursor JSR2
|
|
|
|
BRK
|
|
|
|
@play ( pitch -- )
|
|
|
|
DUP #0c MOD .last-note STZ
|
|
.Audio0/pitch DEO
|
|
|
|
RTN
|
|
|
|
@draw-cursor ( -- )
|
|
|
|
( clear last cursor )
|
|
;cursor .Screen/addr DEO2
|
|
.pointer/x LDZ2 .Screen/x DEO2
|
|
.pointer/y LDZ2 .Screen/y DEO2
|
|
#30 .Screen/color DEO
|
|
( record pointer positions )
|
|
.Mouse/x DEI2 DUP2 .pointer/x STZ2 .Screen/x DEO2
|
|
.Mouse/y DEI2 DUP2 .pointer/y STZ2 .Screen/y DEO2
|
|
( colorize on state )
|
|
#31 [ .Mouse/state DEI #00 ! ] + .Screen/color DEO
|
|
|
|
RTN
|
|
|
|
@draw-octave ( -- )
|
|
|
|
.octave-view/x1 LDZ2 .octave-view/y1 LDZ2
|
|
|
|
OVR2 OVR2 ;keys-left-icns #21 .last-note LDZ #00 = + ;draw-key JSR2
|
|
OVR2 #0008 ++ OVR2 ;keys-middle-icns #21 .last-note LDZ #02 = + ;draw-key JSR2
|
|
OVR2 #0010 ++ OVR2 ;keys-right-icns #21 .last-note LDZ #04 = + ;draw-key JSR2
|
|
OVR2 #0018 ++ OVR2 ;keys-left-icns #21 .last-note LDZ #05 = + ;draw-key JSR2
|
|
OVR2 #0020 ++ OVR2 ;keys-middle-icns #21 .last-note LDZ #07 = + ;draw-key JSR2
|
|
OVR2 #0028 ++ OVR2 ;keys-middle-icns #21 .last-note LDZ #09 = + ;draw-key JSR2
|
|
SWP2 #0030 ++ SWP2 ;keys-right-icns #21 .last-note LDZ #0b = + ;draw-key JSR2
|
|
|
|
.octave-view/x1 LDZ2 #0048 ++ .Screen/x DEO2
|
|
|
|
;arrow-icns .Screen/addr DEO2
|
|
.octave-view/y1 LDZ2 .Screen/y DEO2
|
|
#21 .Screen/color DEO
|
|
|
|
;arrow-icns #0008 ++ .Screen/addr DEO2
|
|
.octave-view/y1 LDZ2 #0010 ++ .Screen/y DEO2
|
|
#21 .Screen/color DEO
|
|
|
|
;font-hex .octave LDZ #03 + #00 SWP 8** ++ .Screen/addr DEO2
|
|
.octave-view/y1 LDZ2 #0008 ++ .Screen/y DEO2
|
|
#23 .Screen/color DEO
|
|
|
|
RTN
|
|
|
|
@draw-key ( x* y* addr* color -- )
|
|
|
|
STH
|
|
.Screen/addr DEO2
|
|
SWP2 .Screen/x DEO2
|
|
DUP2 #0018 ++
|
|
&loop
|
|
( move ) OVR2 .Screen/y DEO2
|
|
( draw ) STHkr .Screen/color DEO
|
|
( incr ) .Screen/addr DEI2 #0008 ++ .Screen/addr DEO2
|
|
( incr ) SWP2 #0008 ++ SWP2
|
|
LTH2k ,&loop JCN
|
|
POP2 POP2
|
|
POPr
|
|
|
|
RTN
|
|
|
|
@draw-adsr ( -- )
|
|
|
|
( adsr )
|
|
.adsr-view/x1 LDZ2 .adsr-view/y1 LDZ2
|
|
.Audio0/adsr DEI #04 SFT
|
|
;draw-knob JSR2
|
|
.adsr-view/x1 LDZ2 #0018 ++ .adsr-view/y1 LDZ2
|
|
.Audio0/adsr DEI #0f AND
|
|
;draw-knob JSR2
|
|
.adsr-view/x1 LDZ2 #0030 ++ .adsr-view/y1 LDZ2
|
|
.Audio0/adsr #01 + DEI #04 SFT
|
|
;draw-knob JSR2
|
|
.adsr-view/x1 LDZ2 #0048 ++ .adsr-view/y1 LDZ2
|
|
.Audio0/adsr #01 + DEI #0f AND
|
|
;draw-knob JSR2
|
|
( volume )
|
|
.adsr-view/x2 LDZ2 #0028 -- .adsr-view/y1 LDZ2
|
|
.Audio0/volume DEI #04 SFT
|
|
;draw-knob JSR2
|
|
.adsr-view/x2 LDZ2 #0010 -- .adsr-view/y1 LDZ2
|
|
.Audio0/volume DEI #0f AND
|
|
;draw-knob JSR2
|
|
|
|
RTN
|
|
|
|
@draw-wave ( -- )
|
|
|
|
( clear )
|
|
.wave-view/x1 LDZ2
|
|
.wave-view/y1 LDZ2
|
|
.wave-view/x2 LDZ2 #0001 ++
|
|
.wave-view/y2 LDZ2
|
|
#00 ;fill-rect JSR2
|
|
|
|
#01 ;draw-wave-length JSR2
|
|
|
|
.wave-view/x1 LDZ2 .Screen/x DEO2
|
|
|
|
( waveform )
|
|
#00 #ff
|
|
&loop
|
|
( dotted line )
|
|
OVR #01 AND ,&no-dot JCN
|
|
.wave-view/y1 LDZ2 #0010 ++ .Screen/y DEO2
|
|
#03 .Screen/color DEO
|
|
&no-dot
|
|
OVR TOS .Audio0/addr DEI2 ++ LDA
|
|
#02 /
|
|
TOS 4// .wave-view/y1 LDZ2 ++ .Screen/y DEO2
|
|
.Screen/x DEI2 #0001 ++ .Screen/x DEO2
|
|
( draw ) OVR .Audio0/length DEI2 SWP POP > #02 * #01 + .Screen/color DEO
|
|
( incr ) INCR
|
|
LTHk ,&loop JCN
|
|
POP2
|
|
|
|
( range )
|
|
.wave-view/x1 LDZ2 .Screen/x DEO2
|
|
.wave-view/y1 LDZ2 #0010 -- .Screen/y DEO2
|
|
.Audio0/addr DEI2 #22 ;draw-short JSR2
|
|
.wave-view/x2 LDZ2 #0020 -- .Screen/x DEO2
|
|
.Audio0/length DEI2 #22 ;draw-short JSR2
|
|
|
|
RTN
|
|
|
|
@draw-wave-length ( color -- )
|
|
|
|
STH
|
|
.wave-view/x1 LDZ2 .Audio0/length DEI2 ++ .Screen/x DEO2
|
|
.wave-view/y1 LDZ2 DUP2 #0020 ++
|
|
&loop
|
|
OVR2 .Screen/y DEO2
|
|
( draw ) STHkr .Screen/color DEO
|
|
( incr ) SWP2 #0001 ++ SWP2
|
|
LTH2k ,&loop JCN
|
|
POP2 POP2
|
|
POPr
|
|
|
|
RTN
|
|
|
|
@draw-knob ( x* y* value -- )
|
|
|
|
( load ) STH .Screen/y DEO2 .Screen/x DEO2
|
|
;knob-icns .Screen/addr DEO2
|
|
( draw ) #21 .Screen/color DEO
|
|
.Screen/x DEI2 #0008 ++ .Screen/x DEO2
|
|
;knob-icns #0008 ++ .Screen/addr DEO2
|
|
( draw ) #21 .Screen/color DEO
|
|
.Screen/y DEI2 #0008 ++ .Screen/y DEO2
|
|
;knob-icns #0018 ++ .Screen/addr DEO2
|
|
( draw ) #21 .Screen/color DEO
|
|
.Screen/x DEI2 #0008 -- .Screen/x DEO2
|
|
;knob-icns #0010 ++ .Screen/addr DEO2
|
|
( draw ) #21 .Screen/color DEO
|
|
.Screen/x DEI2 #0004 ++ .Screen/x DEO2
|
|
.Screen/y DEI2 #0008 ++ .Screen/y DEO2
|
|
;font-hex #00 STHkr #08 * ++ .Screen/addr DEO2
|
|
( draw ) #21 .Screen/color DEO
|
|
.Screen/x DEI2 #0004 -- #00 #00 STHkr ;knob-offsetx ++ LDA ++ .Screen/x DEO2
|
|
.Screen/y DEI2 #0010 -- #00 #00 STHr ;knob-offsety ++ LDA ++ .Screen/y DEO2
|
|
;knob-icns #0020 ++ .Screen/addr DEO2
|
|
( draw ) #25 .Screen/color DEO
|
|
|
|
RTN
|
|
|
|
@draw-short ( short* color -- )
|
|
|
|
STH SWP
|
|
DUP #04 SFT TOS 8** ;font-hex ++ .Screen/addr DEO2
|
|
( draw ) STHkr .Screen/color DEO
|
|
#0f AND TOS 8** ;font-hex ++ .Screen/addr DEO2
|
|
.Screen/x DEI2 #0008 ++ .Screen/x DEO2
|
|
( draw ) STHkr .Screen/color DEO
|
|
DUP #04 SFT TOS 8** ;font-hex ++ .Screen/addr DEO2
|
|
.Screen/x DEI2 #0008 ++ .Screen/x DEO2
|
|
( draw ) STHkr .Screen/color DEO
|
|
#0f AND TOS 8** ;font-hex ++ .Screen/addr DEO2
|
|
.Screen/x DEI2 #0008 ++ .Screen/x DEO2
|
|
( draw ) STHr .Screen/color DEO
|
|
|
|
RTN
|
|
|
|
@fill-rect ( x1* y1* x2* y2* color -- )
|
|
|
|
.color STZ
|
|
( x1 x2 y1 y2 ) ROT2 SWP2
|
|
&ver
|
|
( save ) OVR2 .Screen/y DEO2
|
|
STH2 STH2 OVR2 OVR2
|
|
&hor
|
|
( save ) OVR2 .Screen/x DEO2
|
|
( draw ) .color LDZ .Screen/color DEO
|
|
( incr ) SWP2 #0001 ++ SWP2
|
|
OVR2 OVR2 LTS2 ,&hor JCN
|
|
POP2 POP2 STH2r STH2r
|
|
( incr ) SWP2 #0001 ++ SWP2
|
|
OVR2 OVR2 LTS2 ,&ver JCN
|
|
POP2 POP2 POP2 POP2
|
|
|
|
RTN
|
|
|
|
@within-rect ( x* y* rect -- flag )
|
|
|
|
STH
|
|
( y < rect.y1 ) DUP2 STHkr #02 ADD LDZ2 LTH2 ,&skip JCN
|
|
( y > rect.y2 ) DUP2 STHkr #06 ADD LDZ2 GTH2 ,&skip JCN
|
|
SWP2
|
|
( x < rect.x1 ) DUP2 STHkr LDZ2 LTH2 ,&skip JCN
|
|
( x > rect.x2 ) DUP2 STHkr #04 ADD LDZ2 GTH2 ,&skip JCN
|
|
POP2 POP2 POPr
|
|
#01
|
|
RTN
|
|
&skip
|
|
POP2 POP2 POPr
|
|
#00
|
|
|
|
RTN
|
|
|
|
@cursor
|
|
80c0 e0f0 f8e0 1000
|
|
|
|
@arrow-icns
|
|
0010 387c fe10 1000
|
|
0010 1010 fe7c 3810
|
|
|
|
@notes
|
|
30 32 34 35
|
|
37 39 3b 3c
|
|
|
|
@keys-left-icns
|
|
7c7c 7c7c 7c7c 7c7c
|
|
7c7c 7c7c 7c7c 7e7f
|
|
7f7f 7f7f 7f7f 3e00
|
|
|
|
@keys-middle-icns
|
|
1c1c 1c1c 1c1c 1c1c
|
|
1c1c 1c1c 1c1c 3e7f
|
|
7f7f 7f7f 7f7f 3e00
|
|
|
|
@keys-right-icns
|
|
1f1f 1f1f 1f1f 1f1f
|
|
1f1f 1f1f 1f1f 3f7f
|
|
7f7f 7f7f 7f7f 3e00
|
|
|
|
@knob-icns
|
|
0003 0c10 2020 4040
|
|
00c0 3008 0404 0202
|
|
4040 2020 100c 0300
|
|
0202 0404 0830 c000
|
|
0000 183c 3c18 0000
|
|
|
|
@knob-offsetx
|
|
01 00 00 00 00 01 02 03
|
|
05 06 07 08 08 08 08 07
|
|
|
|
@knob-offsety
|
|
07 06 05 03 02 01 00 00
|
|
00 00 01 02 03 05 06 07
|
|
|
|
@font-hex ( 0-F )
|
|
007c 8282 8282 827c 0030 1010 1010 1010
|
|
007c 8202 7c80 80fe 007c 8202 1c02 827c
|
|
000c 1424 4484 fe04 00fe 8080 7c02 827c
|
|
007c 8280 fc82 827c 007c 8202 1e02 0202
|
|
007c 8282 7c82 827c 007c 8282 7e02 827c
|
|
007c 8202 7e82 827e 00fc 8282 fc82 82fc
|
|
007c 8280 8080 827c 00fc 8282 8282 82fc
|
|
007c 8280 f080 827c 007c 8280 f080 8080
|
|
|
|
@piano-pcm
|
|
8182 8588 8d91 959b a1a6 aaad b2b5 b8bd
|
|
c1c7 cbd0 d5d9 dde1 e5e5 e4e4 e1dc d7d1
|
|
cbc5 bfb8 b2ac a6a2 9c97 928d 8884 807c
|
|
7977 7574 7372 7272 7273 7372 706d 6964
|
|
605b 5650 4d49 4643 4342 4244 4548 4a4d
|
|
5052 5556 5758 5554 5150 4c4a 4744 423f
|
|
3d3c 3a38 3835 3431 3030 2f31 3336 393e
|
|
4449 4e54 5a60 666b 7175 7b82 8990 989e
|
|
a6ab b1b6 babd bebf bfbe bbb9 b6b3 b0ae
|
|
aaa8 a6a3 a19e 9c9a 9997 9696 9798 9b9e
|
|
a1a4 a6a9 a9ac adad adae aeaf b0b0 b1b1
|
|
b3b3 b4b4 b4b3 b3b1 b0ad abab a9a9 a8a8
|
|
a7a5 a19d 9891 8b84 7e77 726e 6b6b 6b6c
|
|
6f71 7477 7776 7370 6c65 5e56 4e48 423f
|
|
3d3c 3b3a 3a39 3838 3839 393a 3c3e 4146
|
|
4a50 575b 6064 686a 6e70 7274 7677 7a7d
|
|
|
|
@violin-pcm
|
|
8186 8d94 9ba0 a3a7 acb1 b5bc c2c7 cacc
|
|
cecf d0d1 d3d5 d8db dee1 e3e5 e6e5 e5e3
|
|
dfdc d7d0 c8c2 bbb2 a99f 968c 847c 746e
|
|
675f 5851 4b43 3e3a 3533 312e 2c2b 2826
|
|
2422 2122 2327 2d34 3c44 4c57 5f68 7075
|
|
7b80 8487 8789 8a8c 8d90 9397 999c 9ea0
|
|
a2a2 a2a0 9c97 9491 8f8e 908f 918f 8e88
|
|
827a 726a 6058 5047 423f 3f40 4245 4748
|
|
4949 4746 4545 4a4f 5863 717f 8b9a a6b1
|
|
b8be c1c1 bfbd bab5 b1af acac aeb1 b7bc
|
|
c2c9 cfd3 d5d4 d3d3 d1ce cbc6 c0ba b3ab
|
|
a39a 8f85 7b72 6c67 6462 605f 5e5d 5b58
|
|
5550 4d49 4848 4949 4a4d 5052 5558 5b5e
|
|
6164 686c 7074 7677 7979 7a7b 7b7a 7977
|
|
7473 6f6e 6b69 696b 6f72 7576 7574 716b
|
|
655d 554e 4742 3f3f 4045 4b52 5a62 6b74
|
|
|
|
@sin-pcm
|
|
8083 8689 8c8f 9295 989b 9ea1 a4a7 aaad
|
|
b0b3 b6b9 bbbe c1c3 c6c9 cbce d0d2 d5d7
|
|
d9db dee0 e2e4 e6e7 e9eb ecee f0f1 f2f4
|
|
f5f6 f7f8 f9fa fbfb fcfd fdfe fefe fefe
|
|
fffe fefe fefe fdfd fcfb fbfa f9f8 f7f6
|
|
f5f4 f2f1 f0ee eceb e9e7 e6e4 e2e0 dedb
|
|
d9d7 d5d2 d0ce cbc9 c6c3 c1be bbb9 b6b3
|
|
b0ad aaa7 a4a1 9e9b 9895 928f 8c89 8683
|
|
807d 7a77 7471 6e6b 6865 625f 5c59 5653
|
|
504d 4a47 4542 3f3d 3a37 3532 302e 2b29
|
|
2725 2220 1e1c 1a19 1715 1412 100f 0e0c
|
|
0b0a 0908 0706 0505 0403 0302 0202 0202
|
|
0102 0202 0202 0303 0405 0506 0708 090a
|
|
0b0c 0e0f 1012 1415 1719 1a1c 1e20 2225
|
|
2729 2b2e 3032 3537 3a3d 3f42 4547 4a4d
|
|
5053 5659 5c5f 6265 686b 6e71 7477 7a7d
|
|
|
|
@tri-pcm
|
|
8082 8486 888a 8c8e 9092 9496 989a 9c9e
|
|
a0a2 a4a6 a8aa acae b0b2 b4b6 b8ba bcbe
|
|
c0c2 c4c6 c8ca ccce d0d2 d4d6 d8da dcde
|
|
e0e2 e4e6 e8ea ecee f0f2 f4f6 f8fa fcfe
|
|
fffd fbf9 f7f5 f3f1 efed ebe9 e7e5 e3e1
|
|
dfdd dbd9 d7d5 d3d1 cfcd cbc9 c7c5 c3c1
|
|
bfbd bbb9 b7b5 b3b1 afad aba9 a7a5 a3a1
|
|
9f9d 9b99 9795 9391 8f8d 8b89 8785 8381
|
|
7f7d 7b79 7775 7371 6f6d 6b69 6765 6361
|
|
5f5d 5b59 5755 5351 4f4d 4b49 4745 4341
|
|
3f3d 3b39 3735 3331 2f2d 2b29 2725 2321
|
|
1f1d 1b19 1715 1311 0f0d 0b09 0705 0301
|
|
0103 0507 090b 0d0f 1113 1517 191b 1d1f
|
|
2123 2527 292b 2d2f 3133 3537 393b 3d3f
|
|
4143 4547 494b 4d4f 5153 5557 595b 5d5f
|
|
6163 6567 696b 6d6f 7173 7577 797b 7d7f
|
|
|
|
@saw-pcm
|
|
8282 8183 8384 8685 8888 8889 8a8b 8c8c
|
|
8e8e 8f90 9092 9193 9494 9596 9699 9899
|
|
9b9a 9c9c 9c9d 9ea0 a1a0 a2a2 a3a5 a4a6
|
|
a7a7 a9a8 a9aa aaac adad aeae b0b0 b1b3
|
|
b2b4 b5b5 b6b7 b9b8 b9bb babc bdbc bdbe
|
|
bfc1 bfc1 c3c1 c4c5 c5c6 c6c7 c9c7 cbca
|
|
cbcc cdcd cfcf d2d0 d2d2 d2d5 d4d5 d6d7
|
|
d8d8 d9dc d9df dadf dce1 dde5 dce6 dceb
|
|
cb1f 1b1e 1c21 1c21 1f23 2025 2127 2329
|
|
2529 2829 2a2b 2b2e 2d2f 302f 3231 3234
|
|
3334 3536 3836 3939 3a3b 3b3d 3e3d 3f40
|
|
4042 4242 4444 4646 4748 474a 4a4b 4d4c
|
|
4e4e 4f50 5052 5252 5554 5557 5759 5959
|
|
5b5b 5c5d 5d5f 5e60 6160 6264 6365 6566
|
|
6867 6969 6a6c 6c6d 6d6e 706f 7071 7174
|
|
7475 7576 7777 797a 7a7c 7b7c 7e7d 7f7f
|