|00 @System &vector $2 &wst $1 &rst $1 &eaddr $2 &ecode $1 &pad $1 &r $2 &g $2 &b $2 &debug $1 &halt $1
|20 @Screen &vector $2 &width $2 &height $2 &auto $1 &pad $1 &x $2 &y $2 &addr $2 &pixel $1 &sprite $1

|0100

@on-reset ( -> )
	( | theme )
	#6f04 .System/r DEO2
	#7f00 .System/g DEO2
	#8f00 .System/b DEO2
	( | screen size )
	#00c0
	( ) DUP2 .Screen/width DEO2
	( ) .Screen/height DEO2
	( | pen )
	#0020
	( ) DUP2 .Screen/x DEO2
	( ) .Screen/y DEO2
	( | vector )
	;on-frame .Screen/vector DEO2
	BRK

@on-frame ( -> )
	[ LIT2 &f $2 ] INC2 DUP2 ,&f STR2
	( | end )
	DUP2 #0400 LTH2 ?{
		POP2 #0000 .Screen/vector DEO2
		BRK }
	d2xy
	( | draw line )
	.Screen/y DEI2 diff ,&y STR2
	.Screen/x DEI2 diff ,&x STR2
	#0400
	&l ( -- )
		.Screen/x DEI2k [ LIT2 &x $2 ] ADD2 ROT DEO2
		.Screen/y DEI2k [ LIT2 &y $2 ] ADD2 ROT DEO2
		[ LIT2 01 -Screen/pixel ] DEO
		INC GTHk ?&l
	POP2 BRK

@diff ( a* b* -- dir* )
	EQU2k ?{
		LTH2 ?{ #0001 JMP2r }
		#ffff JMP2r }
	POP2 POP2 #0000 JMP2r

@d2xy ( d* -- x* y* )
	,&t STR2
	#0000
	( ) DUP2 ,&x STR2
	( ) ,&y STR2
	#2001
	&l ( -- )
		#00 OVR STH2
		[ LIT2 &t $2 ] DUP2 #02 SFT2 ,&t STR2
		( ) DUP2 #01 SFT2 #0001 AND2 DUP2 ,&rx STR2
		( ) EOR2 #0001 AND2 ,&ry STR2
		[ LIT2 &x $2 ] [ LIT2 &y $2 ] [ LIT2 &ry $2 ]
		( ) DUP2r [ LIT2r 0001 ] SUB2r
		( | rot )
		ORA ?{
			[ LIT2 &rx $2 ] #0001 NEQ2 ?{
				( rx-n-1 ) SWP2 STH2kr SWP2 SUB2
				( ry-n-1 ) SWP2 STH2kr SWP2 SUB2 }
			( swap ) SWP2 }
		POP2r
		( ) STH2kr ,&ry LDR2 MUL2 ADD2 ,&y STR2
		( ) STH2r ,&rx LDR2 MUL2 ADD2 ,&x STR2
		DUP ADD GTHk ?&l
	POP2
	( ) ,&x LDR2 #20 SFT2 #0020 ADD2
	( ) ,&y LDR2 #20 SFT2 #0020 ADD2 JMP2r