mirror of
https://github.com/tildearrow/furnace.git
synced 2024-11-30 08:23:01 +00:00
40 lines
1.6 KiB
Text
40 lines
1.6 KiB
Text
dnl @synopsis AX_CHECK_COMPILER_FLAGS(FLAGS, [ACTION-SUCCESS], [ACTION-FAILURE])
|
|
dnl @summary check whether FLAGS are accepted by the compiler
|
|
dnl @category Misc
|
|
dnl
|
|
dnl Check whether the given compiler FLAGS work with the current language's
|
|
dnl compiler, or whether they give an error. (Warnings, however, are
|
|
dnl ignored.)
|
|
dnl
|
|
dnl ACTION-SUCCESS/ACTION-FAILURE are shell commands to execute on
|
|
dnl success/failure.
|
|
dnl
|
|
dnl @version 2005-05-30
|
|
dnl @license GPLWithACException
|
|
dnl @author Steven G. Johnson <stevenj@alum.mit.edu> and Matteo Frigo.
|
|
AC_DEFUN([AX_CHECK_COMPILER_FLAGS],
|
|
[AC_PREREQ(2.59) dnl for _AC_LANG_PREFIX
|
|
AC_MSG_CHECKING([whether _AC_LANG compiler accepts $1])
|
|
dnl Some hackery here since AC_CACHE_VAL can't handle a non-literal varname:
|
|
AS_LITERAL_IF([$1],
|
|
[AC_CACHE_VAL(AS_TR_SH(ax_cv_[]_AC_LANG_ABBREV[]_flags_$1), [
|
|
ax_save_FLAGS=$[]_AC_LANG_PREFIX[]FLAGS
|
|
_AC_LANG_PREFIX[]FLAGS="$1"
|
|
AC_COMPILE_IFELSE([AC_LANG_PROGRAM()],
|
|
AS_TR_SH(ax_cv_[]_AC_LANG_ABBREV[]_flags_$1)=yes,
|
|
AS_TR_SH(ax_cv_[]_AC_LANG_ABBREV[]_flags_$1)=no)
|
|
_AC_LANG_PREFIX[]FLAGS=$ax_save_FLAGS])],
|
|
[ax_save_FLAGS=$[]_AC_LANG_PREFIX[]FLAGS
|
|
_AC_LANG_PREFIX[]FLAGS="$1"
|
|
AC_COMPILE_IFELSE([AC_LANG_PROGRAM()],
|
|
eval AS_TR_SH(ax_cv_[]_AC_LANG_ABBREV[]_flags_$1)=yes,
|
|
eval AS_TR_SH(ax_cv_[]_AC_LANG_ABBREV[]_flags_$1)=no)
|
|
_AC_LANG_PREFIX[]FLAGS=$ax_save_FLAGS])
|
|
eval ax_check_compiler_flags=$AS_TR_SH(ax_cv_[]_AC_LANG_ABBREV[]_flags_$1)
|
|
AC_MSG_RESULT($ax_check_compiler_flags)
|
|
if test "x$ax_check_compiler_flags" = xyes; then
|
|
m4_default([$2], :)
|
|
else
|
|
m4_default([$3], :)
|
|
fi
|
|
])dnl AX_CHECK_COMPILER_FLAGS
|